Das letzte Update war vor 11. August 2022 von schaechner
Um eine Update auf einem nicht unterstützen Gerät zu installieren, brauchen Sie zuerst Windows 11 auf ihrem nicht unterstützen Gerät. Das machen Sie am Besten mit dieser Anleitung:
Wie installiere ich Windows 11 auf einem nicht unterstützen PC? – Schächner
Erforderliches:
- einen nicht unterstützen PC mit Windows 11
- ein Microsoftkonto mit dem Sie bei den Insidern sind
Zuerst müssen Sie dem Dev-Channel beitreten. Das machen Sie, indem Sie die Gruppenrichtlinien öffnen und in diesen Pfad gehen:
Computerkonfiguration -> Administrative Vorlagen -> Windows-Komponenten -> [runter bis zu] Windows Update -> Vom Windows Update angebotene Updates verwalten -> Vorabversionen erhalten
Anschließend auf ‚Vorabversionen erhalten‘ doppelklicken, auf ‚Aktiviert‘ gehen, und den Dev-Channel auswählen. Das Bild dazu ist hier unten:
Sollten Sie jetzt ein Windows-Update anfangen, hängt dies meistens bei 6, oder 8%, und es kommt ein Popup, dass der TPM 2.0 nicht unterstützt wird.
Wechseln Sie jetzt mit der Windows-Taste + i in die Einstellungen. Dort gehen Sie auf ‚Datenschutz und Sicherheit‘ und wählen ‚Diagnose & Feedback‘ aus. Hier müssen Sie den Schalter von ‚Optionale Diagnosedaten senden‘ einschalten!
Jetzt müssen Sie eine Windows-Befehlsskript-Datei erstellen. Das machen Sie mit dem Editor.
Sie können den Editor über die Windows-Suche öffnen.
Anschließend fügen Sie in die Datei diesen Inhalt hinzu:
@(set '(=)||' <# lean and mean cmd / powershell hybrid #> @'
::# Get 11 on 'unsupported' PC via Windows Update or mounted ISO (no patching needed)
::# if wu download stuck at 0% use OfflineInsiderEnroll by whatever127 and abbodi1406
::# V9+ rebased on cmd due to defender transgression; skip already patched media (0b)
@echo off & title get 11 on 'unsupported' PC || AveYo 2022.05.11
if /i "%~f0" neq "%ProgramData%\get11.cmd" goto setup
set CLI=%*& set SOURCES=%SystemDrive%\$WINDOWS.~BT\Sources& set MEDIA=.& set /a VER=11
if not defined CLI (exit /b) else if not exist %SOURCES%\SetupHost.exe (exit /b)
if not exist %SOURCES%\SetupCore.exe mklink /h %SOURCES%\SetupCore.exe %SOURCES%\SetupHost.exe >nul
for %%W in (%CLI%) do if /i %%W == /InstallFile (set "MEDIA=") else if not defined MEDIA set "MEDIA=%%~dpW"
set /a restart_application=0x800705BB & call set CLI=%%CLI:%1 =%%&;
set /a incorrect_parameter=0x80070057 & set SRV=%CLI:/Product Client =%&;
set /a launch_option_error=0xc190010a & set SRV=%SRV:/Product Server =%&;
powershell -win 1 -nop -c ";"
if %VER% == 11 for %%W in ("%MEDIA%appraiserres.dll") do if exist %%W if %%~zW == 0 set AlreadyPatched=1 & set /a VER=10
if %VER% == 11 findstr /r "P.r.o.d.u.c.t.V.e.r.s.i.o.n...1.0.\..0.\..2.[25]" %SOURCES%\SetupHost.exe >nul 2>nul || set /a VER=10
if %VER% == 11 if not exist "%MEDIA%EI.cfg" (echo;[Channel]>%SOURCES%\EI.cfg & echo;_Default>>%SOURCES%\EI.cfg) 2>nul
if %VER% == 11 set CLI=/Product Server /Compat IgnoreWarning /MigrateDrivers All /Telemetry Disable %SRV%&;
%SOURCES%\SetupCore.exe %CLI%
if %errorlevel% == %restart_application% %SOURCES%\SetupCore.exe %CLI%
exit /b
:setup
::# elevate with native shell by AveYo
>nul reg add hkcu\software\classes\.Admin\shell\runas\command /f /ve /d "cmd /x /d /r set \"f0=%%2\"& call \"%%2\" %%3"& set _= %*
>nul fltmc|| if "%f0%" neq "%~f0" (cd.>"%temp%\runas.Admin" & start "%~n0" /high "%temp%\runas.Admin" "%~f0" "%_:"=""%" & exit /b)
::# lean xp+ color macros by AveYo: %<%:af " hello "%>>% & %<%:cf " w\"or\"ld "%>% for single \ / " use .%|%\ .%|%/ \"%|%\"
for /f "delims=:" %%s in ('echo;prompt $h$s$h:^|cmd /d') do set "|=%%s"&set ">>=\..\c nul&set /p s=%%s%%s%%s%%s%%s%%s%%s<nul&popd"
set "<=pushd "%appdata%"&2>nul findstr /c:\ /a" &set ">=%>>%&echo;" &set "|=%|:~0,1%" &set /p s=\<nul>"%appdata%\c"
::# toggle when launched without arguments, else jump to arguments: "install" or "remove"
set CLI=%*& set IFEO=HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Image File Execution Options&;
wmic /namespace:"\\root\subscription" path __EventFilter where Name="Skip TPM Check on Dynamic Update" delete >nul 2>nul & rem v1
reg delete "%IFEO%\vdsldr.exe" /f 2>nul & rem v2 - v5
if /i "%CLI%"=="" reg query "%IFEO%\SetupHost.exe\0" /v Debugger >nul 2>nul && goto remove || goto install
if /i "%~1"=="install" (goto install) else if /i "%~1"=="remove" goto remove
:install
::@prompt $H & echo on
copy /y "%~f0" "%ProgramData%\get11.cmd" >nul 2>nul
reg add "%IFEO%\SetupHost.exe" /f /v UseFilter /d 1 /t reg_dword >nul
reg add "%IFEO%\SetupHost.exe\0" /f /v FilterFullPath /d "%SystemDrive%\$WINDOWS.~BT\Sources\SetupHost.exe" >nul
reg add "%IFEO%\SetupHost.exe\0" /f /v Debugger /d "%ProgramData%\get11.cmd" >nul
::@echo off & echo;
%<%:f0 " Skip TPM Check on Dynamic Update V9+ "%>>% & %<%:2f " INSTALLED "%>>% & %<%:f0 " run again to remove "%>%
if /i "%CLI%"=="" timeout /t 7
exit /b
:remove
::@prompt $H & echo on
del /f /q "%ProgramData%\get11.cmd" >nul 2>nul
reg delete "%IFEO%\SetupHost.exe" /f >nul 2>nul
::@echo off & echo;
%<%:f0 " Skip TPM Check on Dynamic Update V9+ "%>>% & %<%:df " REMOVED "%>>% & %<%:f0 " run again to install "%>%
if /i "%CLI%"=="" timeout /t 7
exit /b
'@); $0 = "$env:temp\Skip_TPM_Check_on_Dynamic_Update.cmd"; ${(=)||} | out-file $0 -encoding default -force; & $0
# press enterIst das gemacht, können Sie mit strg+s die Datei speichern.
Als Name können Sie tpm2.0.cmd wählen. Wichtig ist nur, das die Datei eine Endung mit .cmd haben.
Als Dateitype wählen Sie ‚Alle Dateien‘ aus.
Hier ist das Video dazu:
Wir wollen nochmals betonen, dass dies nur für die Personengruppe geeignet ist, Die wissen, was sie tun. All das ist nicht offiziell von Microsoft und wir übernehmen keine Haftung für Schäden oder Dateiverlust, falls so etwas auftreten würde. Dies ist jedoch nur selten der Fall.
Wir hoffen, wir konnten Ihnen mit diesem Artikel helfen.
Falls Sie noch Fragen haben, können Sie diese gerne in unserer eigenen Community (community.schächner.de) stellen!
